package {
	import flash.display.BitmapData;
	import flash.geom.Rectangle;

	/**
	 * BitmapData のユーティリティクラスです.
	 *
	 * @langversion ActionScript 3.0
	 * @playerversion Flash 9.0
	 *
	 * @author dsk
	 * @since 2009/05/20
	 */
	public class BitmapDataUtil {

		/**
		 * （findColor パラメータが true に設定されている場合）ビットマップイメージ内の指定された色のすべてのピクセルを完全に囲む矩形領域を判別します。または、（findColor パラメータが false に設定されている場合）指定された色ではないすべてのピクセルを完全に囲む矩形領域を判別します。
		 *
		 * @param	bitmapData	ビットマップデータです。
		 * @param	mask		対象となる ARGB カラーのビットを指定する 16 進数値です。カラー値は、&（ビット単位の論理積（AND））演算子を使用して、この 16 進数値と組み合わせられます。
		 * @param	color		16 進数値です。（findColor が true に設定されている場合は）一致すべき ARGB カラー、一致すべきでない ARGB カラー（findColor が false に設定されている場合）をそれぞれ指定します。
		 * @param	findColor	値が true に設定された場合、イメージ内のカラー値の境界を返します。 値が false に設定された場合、イメージ内の指定されたカラーが存在しない領域の境界を返します。
		 * @return
		 */
		public static function getColorBoundsRect(bitmapData:BitmapData, mask:uint = 0x00000000, color:uint = 0xff000000, findColor:Boolean = true):Rectangle {
			var rectangle:Rectangle = bitmapData.getColorBoundsRect(mask, color, findColor);

			var maskA:uint = mask >> 24 & 0xff;
			var maskRGB:uint = mask & 0xffffff;
			var leftTopARGB:uint = bitmapData.getPixel32(0, 0);
			var leftTopA:uint = leftTopARGB >> 24 & 0xff;
			var leftTopRGB:uint = leftTopARGB & 0xffffff;

			var resultA:uint = leftTopA & maskA;
			var resultRGB:uint = leftTopRGB & maskRGB
			var resultARGB:uint = (resultA << 24) + resultRGB;

			if (findColor) {
				if (resultARGB == color) {
					rectangle = rectangle.union(new Rectangle(0, 0, 1, 1));
				}
			} else {
				if (resultARGB != color) {
					rectangle = rectangle.union(new Rectangle(0, 0, 1, 1));
				}
			}

			return rectangle;
		}


	}

}

package  {
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.geom.Rectangle;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;

	public class TestBug_BitmapData extends Sprite {

		private var _counter:int;

		public function TestBug_BitmapData() {
			_counter = 0;

			test(new Rectangle(0, 0, 1, 1));
			test(new Rectangle(29, 0, 1, 1));
			test(new Rectangle(29, 29, 1, 1));
			test(new Rectangle(0, 29, 1, 1));
			test(new Rectangle(0, 1, 1, 1));
			test(new Rectangle(1, 0, 1, 1));
			test(new Rectangle(1, 1, 1, 1));
			test(new Rectangle(0, 0, 1, 2));
			test(new Rectangle(0, 0, 2, 1));
		}

		private function test(rectangle:Rectangle):void {
			_counter ++;

			var id:int = _counter;
			var bitmapData:BitmapData = new BitmapData(30, 30, false, 0xCCCCCC);
			bitmapData.fillRect(rectangle, 0xFF0000);

			var bitmap:Bitmap = new Bitmap(bitmapData);
			bitmap.x = 50;
			bitmap.y = 50 * id;
			addChild(bitmap);

			var textFormat:TextFormat = new TextFormat();
			textFormat.font = '_等幅';
			var textField:TextField = new TextField();
			textField.autoSize = TextFieldAutoSize.LEFT;
			textField.appendText('test' + id.toString() + '\n');
			textField.appendText(bitmapData.getColorBoundsRect(0xFF0000, 0xFF0000, true).toString());
			textField.setTextFormat(textFormat);
			textField.x = 100;
			textField.y = 50 * id;
			addChild(textField);
		}

	}

}